SPSS: PROGRAMAS E ROTINAS COMPLEMENTARES (SYNTAX FILES)

 

Proporções

 

Teste para a diferença entre duas proporções correlacionadas
[Nível de significação, intervalo de confiança e poder observado]

Esta sintaxe efectua o Teste de McNemar (aproximações via distribuições normal e do qui-quadrado e probabilidade exacta pela distribuição binomial) da diferença entre duas proporções correlacionadas, calculando, igualmente, o intervalo de confiança da diferença e o poder observado.

Com vista a facilitar a compreensão do modo de introdução dos dados, começamos com um exemplo de Guilford e Fruchter (1978):

Suponha que administrou dois itens de um teste a uma amostra de 100 estudantes. O Item 1 foi respondido correctamente por 60 estudantes e o Item 2 por 70 estudantes. Será o Item 2 realmente mais fácil do que o Item 1? (p. 126).

Para utilizar a sintaxe e testar a diferença entre as proporções correlacionadas de 0.60 e 0.70, deve organizar os efectivos da amostra da seguinte forma:

 

V2 (Item 2)

0

Incorrecto

1

Correcto

V1 (Item 1)

1

Correcto

b

5

a

55

0

Incorrecto

d

25

c

15

No exemplo de Guilford e Fruchter, os estudantes das células a e d comportaram-se de igual modo em relação aos dois itens (55 acertaram os dois e 25 falharam os dois) ao passo que os estudantes das células b e c tiveram um comportamento dissonante: acertaram num dos itens e falharam no outro (5 acertaram no Item 1 e falharam no Item 2 e 15 fizeram o inverso). Como o Teste de McNemar se centra na informação das células b e c, deve respeitar as designações aqui adoptadas, fazendo igualmente equivaler, consoante o seu problema:

1 = Correcto / Sim / Presente /Sucesso / etc.
0 = Incorrecto / Não / Ausente / Insucesso / etc.

Para para além dos efectivos das quatro células, apenas deve especificar o nível de confiança (NC) para a determinação dos limites inferior (LIM_INF) e superior (LIM_SUP) do intervalo de confiança e o nível se significação (ALFA) a adoptar no cálculo do poder observado (PODER) .

O output divide-se em sete partes:

1) N (total de casos na amostra), P1 e P2 (proporções correlacionadas a comparar), Z (z observado) e probabilidades bilateral (PZ_BI) e unilateral (PZ_UNI);

2) Z_C, PZ_BI_C e PZ_UNI_C (valor de z corrigido para a continuidade e respectivas probabilidade bilateral e unilateral) – cf. Nota 1;

3) P_BC (proporção dos casos na célula b em relação ao total de casos nas células b e c), P_P (= 0.50; proporção constante na população com a qual é comparada P_BC), DIF (diferença entre P_BC e P_P), NC (nível de confiança, introduzido pelo utilizador) e limites inferior (LIM_INF) e superior (LIM_SUP) do intervalo de confiança (cf. Nota 2);

4) ALFA (nível de significação para a determinação do poder, introduzido pelo utilizador) e PODER (cf. Nota 2);

5) QUI_2, GL, PQUI_BI e PQUI_UNI (valor do Qui-Quadrado observado, graus de liberdade e probabilidade bilateral e unilateral);

6) QUI_2_C, GL, PQUI_BIC e PQUI_UNC (valor do Qui-Quadrado observado, graus de liberdade e probabilidades bilateral e unilateral, corrigidas para a continuidade) – cf. Nota 1;

7) Tabela de contigência reproduzindo os dados introduzidos pelo utilizador, probabilidades exactas do Teste de McNemar (cf. Nota 1) e coeficiente de correlação entre as duas variáveis (f = Phi, um caso particular do coeficiente de correlação linear entre duas variáveis dicotómicas).

*** Teste para a diferença entre duas proporções correlacionadas

*** [Nível de Significação, Intervalo de Confiança e Poder Observado]

*** Valentim Rodrigues Alferes (Universidade de Coimbra, 2003)

*** valferes@fpce.uc.pt

 

NEW FILE.

INPUT PROGRAM.

LOOP X=1 TO 1.

END CASE.

END LOOP.

END FILE.

END INPUT PROGRAM.

* Introduza os efectivos das células “a”, “b”, “c” e “d”.

COMPUTE a = 55.

COMPUTE b = 5.

COMPUTE c = 15.

COMPUTE d = 25.

* Introduza o nível de confiança (em percentagem) para a determinação

* do intervalo de confiança (por defeito, NC = 95).

COMPUTE NC = 95.

* Introduza o alfa para o cálculo do poder (por defeito, ALFA = 0.05).

COMPUTE ALFA = 0.05.

COMPUTE N=B+A+D+C.

COMPUTE P1=(B+A)/N.

COMPUTE P2=(A+C)/N.

COMPUTE Z=(B-C)/SQR(B+C).

COMPUTE ZABS=ABS(Z).

COMPUTE PZ_BI=(1-CDFNORM(ZABS))*2.

COMPUTE PZ_UNI=1-CDFNORM(ZABS).

COMPUTE Z_C=(ABS(B-C)-1)/SQR(B+C).

COMPUTE ZABSC=ABS(Z_C).

COMPUTE PZ_BI_C=(1-CDFNORM(ZABSC))*2.

COMPUTE PZ_UNI_C=1-CDFNORM(ZABSC).

IF (Z<0) Z_C=-1*Z_C.

COMPUTE QUI_2=(B-C)**2/(B+C).

COMPUTE GL=1.

COMPUTE PQUI_BI=1-CDF.CHISQ(QUI_2,GL).

COMPUTE PQUI_UNI=(1-CDF.CHISQ(QUI_2,GL))/2.

COMPUTE QUI_2_C=(ABS(B-C)-1)**2/(B+C).

COMPUTE PQUI_BIC=1-CDF.CHISQ(QUI_2_C,GL).

COMPUTE PQUI_UNC=(1-CDF.CHISQ(QUI_2_C,GL))/2.

COMPUTE P_P=0.50.

COMPUTE P_BC=B/(B+C).

COMPUTE DIF=P_BC-P_P.

COMPUTE NBC=B+C.

COMPUTE Q=1-P_BC.

COMPUTE Z_NC=IDF.NORMAL(NC/100+(1-NC/100)/2,0,1).

COMPUTE AX=Z_NC**2/NBC.

COMPUTE LIM_INF=(P_BC+AX/2-Z_NC*SQR(((P_BC*Q)/NBC)+(AX/(4*NBC)))) /(1+AX).

COMPUTE LIM_SUP=(P_BC+AX/2+Z_NC*SQR(((P_BC*Q)/NBC)+(AX/(4*NBC)))) /(1+AX).

COMPUTE RQP1=SQR(P_BC).

COMPUTE H1=2*ARTAN(RQP1/SQR(-RQP1*RQP1+1)).

COMPUTE RQP2=SQR(P_P).

COMPUTE H2=2*ARTAN(RQP2/SQR(-RQP2*RQP2+1)).

COMPUTE HDIF=H1-H2.

COMPUTE Z_ALFA=IDF.NORMAL(1-ALFA/2,0,1).

COMPUTE ZPODER1=ABS(HDIF*SQR(2))*SQR(NBC/2)-Z_ALFA.

COMPUTE ZPODER2=-ABS(HDIF*SQR(2))*SQR(NBC/2)-Z_ALFA.

COMPUTE PODER1=CDF.NORMAL(ZPODER1,0,1).

COMPUTE PODER2=CDF.NORMAL(ZPODER2,0,1).

COMPUTE PODER=PODER1+PODER2.

EXECUTE.

FORMATS N GL NC(F8.0) P1 P2 Z PZ_BI PZ_UNI Z_C PZ_BI_C PZ_UNI_C

QUI_2 PQUI_BI PQUI_UNI QUI_2_C PQUI_BIC PQUI_UNC ALFA PODER

P_BC P_P DIF LIM_INF LIM_SUP (F8.4).

LIST N P1 P2 Z PZ_BI PZ_UNI.

LIST Z_C PZ_BI_C PZ_UNI_C.

LIST P_BC P_P DIF NC LIM_INF LIM_SUP.

LIST ALFA PODER.

LIST QUI_2 GL PQUI_BI PQUI_UNI.

LIST QUI_2_C GL PQUI_BIC PQUI_UNC.

FLIP VARIABLES=A B C D.

COMPUTE V1=0.

COMPUTE V2=0.

EXECUTE.

IF (CASE_LBL='A') V1=1.

IF (CASE_LBL='A') V2=1.

IF (CASE_LBL='B') V1=1.

IF (CASE_LBL='C') V2=1.

COMPUTE FREQ=VAR001.

EXECUTE.

WEIGHT BY FREQ.

CROSSTABS/TABLES=V1 BY V2/FORMAT=AVALUE TABLES

/STATISTIC=PHI MCNEMAR/CELLS=COUNT TOTAL/METHOD=EXACT TIMER(5).

Output (exemplo)

*** Teste para a diferença entre duas proporções correlacionadas

*** [Nível de Significação, Intervalo de Confiança e Poder Observado]

*** Valentim Rodrigues Alferes (Universidade de Coimbra, 2003)

*** valferes@fpce.uc.pt

 

NEW FILE.

[…]

LIST N P1 P2 Z PZ_BI PZ_UNI.

List

       N       P1       P2        Z    PZ_BI   PZ_UNI

 

     100    ,6000    ,7000  -2,2361    ,0253    ,0127

 

Number of cases read:  1    Number of cases listed:  1

 

LIST Z_C PZ_BI_C PZ_UNI_C.

List

     Z_C  PZ_BI_C PZ_UNI_C

 

 -2,0125    ,0442    ,0221

 

Number of cases read:  1    Number of cases listed:  1

 

LIST P_BC P_P DIF NC LIM_INF LIM_SUP.

List

    P_BC      P_P      DIF       NC  LIM_INF  LIM_SUP

 

   ,2500    ,5000    ,2500       95    ,1119    ,4687

 

Number of cases read:  1    Number of cases listed:  1

 

LIST ALFA PODER.

List

    ALFA    PODER

 

   ,0500    ,6486

 

Number of cases read:  1    Number of cases listed:  1

 

LIST QUI_2 GL PQUI_BI PQUI_UNI.

List

   QUI_2       GL  PQUI_BI PQUI_UNI

 

  5,0000        1    ,0253    ,0127

 

Number of cases read:  1    Number of cases listed:  1

 

LIST QUI_2_C GL PQUI_BIC PQUI_UNC.

List

 QUI_2_C       GL PQUI_BIC PQUI_UNC

 

  4,0500        1    ,0442    ,0221

 

Number of cases read:  1    Number of cases listed:  1

 
[…]

Crosstabs

 

 

 

 

Nota 1

As aproximações ao problema pela distribuição normal e pela distribuição do qui-quadrado  (cf. Nota 3) são rigorosamente idênticas (z2 = c2), como se pode confirmar pelas probabilidades corrigidas e não corrigidas para a continuidade nas Partes 1, 2, 5 e 6 do Output.

Para o caso do exemplo, e dado que estamos perante uma hipótese direccional,  interassa-nos a probabilidade unilateral corrigida para a continuidade (p = 0.0221). Esta probabilidade constitui uma boa aproximação à probabilidade exacta dada pela distribuição binomial da Parte 7 do Output (p = 0.0207). Em qualquer dos casos, podemos rejeitar a hipótes nula, i.e., existe evidência suficiente para afirmarmos que o Item 2 é mais fácil do que o Item 1.

Historicamente, o recurso ao Teste z ou ao Teste do Qui-Quadrado encontra justificação na dificuldade em calcular as probabilidades exactas para valores elevados de N. Como o SPSS faz essa tarefa em poucos segundos, recomendamos ao utilizador que indique sempre a probabilidade exacta dada pela distribuição binomial para o Teste de McNemar.

Nota 2

Em conformidade com a lógica do Teste de McNemar, que se baseia exclusivamente na informação das células b e c, o que efectivamente é calculado é o intervalo de confiança  da diferença entre a constante de p = 0.50 na população e a proporção dos casos dissonantes na célula b (5) em relação ao total de casos dissonante (b + c = 5 + 15 = 20) , i.e., a diferença entre uma proporção de 0.25 e um valor na população de 0.50 (como é evidente, se o número de casos nas células b e c fossem idênticos, os itens teriam igual dificuldade). O procedimento é rigorosamente idêntico ao utilizado na sintaxe Teste para uma proporção igual a 0.50 na população.

O mesmo é válido em relação à determinação do poder via aproximação normal, em que o tamanho do efeito e o N se referem apenas às células b e c (cf. Borenstein, Rothstein & Cohen, 2001).

Nota 3

Repare que o Teste do Qui-Quadrado aqui mencionado não é aquele que poderia ober no menu Descriptive Statistics / Crosstabs... pedindo para analisar a tabela de contigência 2 x 2. Se quiser obter directamente o teste nos menus, basta ter uma  variável X com duas categorias e as frequências nas células b  e c na variável FREQ e utilizar o menu Nonparametric Tests / Chi-Square ... (Test Variable = X),  depois de ter pedido que os casos fossem ponderados pela variável FREQ. Em sintaxe:

 

DATA LIST FREE/X(F8.0) FREQ(F8.0).

BEGIN DATA

1 5 2 15

END DATA.

LIST.

WEIGHT BY FREQ .

NPAR TEST/CHISQUARE=X/EXPECTED=EQUAL/METHOD=EXACT TIMER(5).

 

Output

List

       X     FREQ

 

       1        5

       2       15

 

Number of cases read:  2    Number of cases listed:  2

 

NPar Tests

Chi-Square Test

Frequencies

 

 

 

 

Este procedimento é conforme ao que se explicita na Nota 2.

Referências

Borenstein, M., Rothstein, H., & Cohen, J. (2001). SamplePower 2.0 [Computer Manual]. Chicago: SPSS Inc.

Guilford, J. P., & Fruchter, B. (1978). Fundamental statistics in psychology and education (6th ed.). New York: McGraw-Hill.

 

NIIPS / CSEO

SYNTAX FILES

valferes@fpce.uc.pt

Última actualização: 2003-04-09