* Encoding: UTF-8.
*** Planos de Medidas Repetidas (Contrabalanceamento Completo)
*** Valentim Rodrigues Alferes (Universidade de Coimbra, 2002)
*** valferes@fpce.uc.pt
**
** Esta sintaxe determina as possíveis sequências de tratamentos em
** planos de medidas repetidas e atribui aleatoriamente as sequências 
** aos sujeitos, de modo a que cada sequência esteja igualmente 
** representada no plano experimental (contrabalanceamento completo da
** ordem dos tratamentos).
**
** Num plano de medidas repetidas (i.e., um plano em que todos os 
** sujeitos passam por todas as condições ou tratamentos experimentais)
** o número possível de sequências é igual a p! (leia-se p factorial)
** e equivale ao número de permutações entre os tratamentos. 
**
** Sendo k um inteiro, temos:
**
** No. de tratamentos   No. de sequências  Nº de sujeitos requerido
**         [p]                  [p!]              [n = kp!]
**
**          2                 2!=2x1=2       2, 4, 6, 8, 10, 12,... 
**          3               3!=3x2x1=6       6, 12, 18, 24, 30,...
**          4            4!=4x3x2x1=24       24, 48, 72, 94,...
**          5               5!=[…]=120       120, 240, 360,...
**          6               6!=[…]=720       720, 1440,...    
**          7              7!=[…]=5040                
**
** Como se pode constatar, ainda que o contrabalanceanto completo seja 
** a melhor estratégia para minimizar os efeitos da prática e do 
** transfert, as exigências relativas ao número de sujeitos requeridos
** para a investigação limitam o seu uso às situações de 2, 3 ou 4 
** tratamentos (para 5 tratmentos seriam necessários 120 sujeitos 
** para que pelo menos uma sequência de tratamentos fosse aleatoria-
** mente atribuída a cada sujeito; nestas circunstâncias a melhor
** solução é recorrer ao contabalanceamento parcial).

** No exemplo temos:
** 3 tratamentos (A, B, e C) [p = 3]
** 6 sequências de tratamentos [p! = 3! = 6];
** 24 sujeitos [n = 24]);
** 4 sujeitos por sequência de tratamentos [k = n/p! = 24/6 = 4].

DATA LIST FREE /SEQUENC(A10).
* Introduza as sequências de tratamentos (p!).
BEGIN DATA
ABC ACB BAC BCA CAB CBA
END DATA.

* Introduza o número de sujeitos por sequência de tratamentos (n/p!). 
COMPUTE SUBJECTS = 4.
LOOP CASES=1 TO subjects.
XSAVE OUTFILE='%temp%\OUTF1'/KEEP=SEQUENC.
END LOOP.
EXECUTE.
GET FILE='%temp%\OUTF1'.

SET SEED RANDOM.
COMPUTE RANDOM=UNIFORM(1).
SORT CASES BY RANDOM(A).
RANK VARIABLES=RANDOM(A).
COMPUTE ID=RRANDOM.
FORMATS ID(F8.0).
LIST ID SEQUENC.
SORT CASES BY SEQUENC(A) ID(A).
SPLIT FILE SEPARATE BY SEQUENC.
LIST ID.