SPSS: PROGRAMAS E ROTINAS COMPLEMENTARES (SYNTAX FILES)

 

Sintaxes Diversas

 

Correcção de um Teste de Escolha Múltipla

Esta sintaxe corrige automaticamente um teste de escolha múltipla. Para isso, deve ter na file activa do SPSS as respostas dadas ao teste, em variáveis designadas sequencialmente de Q1 a Qn. Em seguida, basta introduzir a chave das respostas correctas e indicar o número de questões do teste.

No exemplo, temos as respostas de 10 sujeitos a um teste de escolha múltipla com 5 questões de 5 alternativas de resposta. As questões têm a designação de Q1, Q2, Q3, Q4 e Q5. Nas respostas dadas pelos sujeitos, os valores 1, 2, 3, 4 e 5 correspondem, respectivamente, à escolha das alíneas a), b), c), d) e e) [cf. Nota 1].

A chave de respostas correctas é, respectivamente para as questões Q1 a Q5, c), a), d), b) e d), o que corresponde aos valores 3, 1, 4, 2 e 4 a introduzir no local apropriado da sintaxe.

No output, para além das respostas originais, obterá a matriz de respostas correctas (R1 a Rn) e o número total de respostas correctas (SOMA) de cada sujeito. Como é evidente, estas variáveis ficam registadas na file activa. Por isso, se desejar suprimir o output ao utilizar a sintaxe em situações reais com um número elevado de sujeitos e de questões, elimine as linhas com os comandos LIST.

Para converter a soma em valores, cf. Nota 2. Para adaptar esta sintaxe a um número diferente de alternativas de resposta, cf. Nota 3. Para uma simulação de respostas ao acaso em 100000 testes de escolha múltipla, cf. outra sintaxe neste site.

** Dados de ilustração (respostas de 10 alunos a 5 questões).

 

DATA LIST FREE/NI(F8.0) NOME(A8) Q1(F8.0) Q2(F8.0) Q3(F8.0) Q4(F8.0)

Q5(F8.0).

BEGIN DATA

1 Manuel 3 1 1 1 2 2 Ana 2 4 3 1 5 3 Maria 3 4 2 5 4 4 Rui 2 1 4 2

3 5 João 1 4 5 3 4 6 Pedro 5 1 4 2 4 7 Inês 3 1 4 2 4 8 Teresa 3 2

2 1 5 9 António 1 1 4 2 4 10 Paula 3 1 4 4 1

END DATA.

 

* Quadro 1: Respostas originais.

LIST.

 

*** Correcção de um teste de escolha múltipla.

*** Valentim Rodrigues Alferes (Universidade de Coimbra, 2003)

*** valferes@fpce.uc.pt

 

* Introduza a chave no local assinalado a azul e o número de questões

* nos seis locais assinalados a vermelho.

 

DO REPEAT C=C1 TO C5

/Chave = 3 1 4 2 4.

COMPUTE C=CHAVE.

END REPEAT.

DO REPEAT R=R1 TO R5/Q=Q1 TO Q5/C=C1 TO C5.

COMPUTE R=Q-C.

END REPEAT.

RECODE R1 TO R5(0=1)(ELSE=0).

COUNT SOMA=R1 TO  R5(1).

EXECUTE.

 

** Quadro 2: Respostas correctas (1) e incorrectas (0) e soma.

FORMATS R1 TO SOMA(F8.0).

LIST NI NOME R1 TO SOMA.

 

Output

** Dados de ilustração (respostas de 10 alunos a 5 questões).

 

DATA LIST FREE/NI(F8.0) NOME(A8) Q1(F8.0) Q2(F8.0) Q3(F8.0) Q4(F8.0)

Q5(F8.0).

BEGIN DATA

 

[...]

 

* Quadro 1: Respostas originais.

LIST.

 

List

 

      NI NOME           Q1       Q2       Q3       Q4       Q5

 

       1 Manuel          3        1        1        1        2

       2 Ana             2        4        3        1        5

       3 Maria           3        4        2        5        4

       4 Rui             2        1        4        2        3

       5 João            1        4        5        3        4

       6 Pedro           5        1        4        2        4

       7 Inês            3        1        4        2        4

       8 Teresa          3        2        2        1        5

       9 António         1        1        4        2        4

      10 Paula           3        1        4        4        1

 

 

Number of cases read:  10    Number of cases listed:  10

 

 

*** Correcção de um teste de escolha múltipla.

 

[...]

 

** Quadro 2: Respostas correctas (1) e incorrectas (0) e soma.

FORMATS R1 TO SOMA(F8.0).

LIST NI NOME R1 TO SOMA.

 

List

 

      NI NOME           R1       R2       R3       R4       R5     SOMA

 

       1 Manuel          1        1        0        0        0        2

       2 Ana             0        0        0        0        0        0

       3 Maria           1        0        0        0        1        2

       4 Rui             0        1        1        1        0        3

       5 João            0        0        0        0        1        1

       6 Pedro           0        1        1        1        1        4

       7 Inês            1        1        1        1        1        5

       8 Teresa          1        0        0        0        0        1

       9 António         0        1        1        1        1        4

      10 Paula           1        1        1        0        0        3

 

Number of cases read:  10    Number of cases listed:  10

Nota 1

Se na sua file original tem as respostas em variáveis alfanuméricas (a, b, c, ...), recodifique-as em variáveis numéricas no menu Transform/Recode, utilizando as correspondências aqui adoptadas (a = 1, b = 2, c = 3, etc.).

Desde que respeite estas correspondências, pode utilizar a sintaxe com qualquer número de alternativas de resposta (cf. Nota 3), idêntico ou diferente para as várias questões de um mesmo teste.

Nota 2

Como pode verificar no output, a Ana errou todas as questões, ao passo que a Inês acertou em todas.

Admitindo que todas as questões têm a mesma cotação, pode transformar a soma em valores (CF), acrescentando estas linhas à sintaxe:

* Introduza o número total de questões (no exemplo, 5 questões).

COMPUTE NQ = 5.

* Introduza a cotação máxima (por exemplo, 20 valores).

COMPUTE VALORES = 20.

COMPUTE CF=SOMA/NQ*VALORES.

EXECUTE.

FORMATS CF(F8.1).

LIST NI NOME CF.

Nota 3

Se, por exemplo, o seu teste tiver 50 questões (Q1 a Q50) com .7 alternativas de resposta [a), b), c), d), e), f) e g), correspondentes, respectivamente, a 1, 2, 3, 4, 5, 6 e 7], deve introduzir as seguintes modificações na sintaxe:

*** Correcção de um teste de escolha múltipla

*** Valentim Rodrigues Alferes (Universidade de Coimbra, 2003)

*** valferes@fpce.uc.pt

 

* Introduza a chave no local assinalado a azul e o número de questões

* nos seis locais assinalados a vermelho.

 

DO REPEAT C=C1 TO C50

/Chave =

1 4 5 3 2 5 3 4 1 1 4 1 5 2 6 7 5 2 6 1 1 6 2 2 5 
7 2 3 1 6 1 4 2 1 5 5 7 3 4 5 2 6 1 4 5 7 3 4 6 1.

COMPUTE C=CHAVE.

END REPEAT.

DO REPEAT R=R1 TO R50/Q=Q1 TO Q50/C=C1 TO C50.

COMPUTE R=Q-C.

END REPEAT.

RECODE R1 TO R50(0=1)(ELSE=0).

COUNT SOMA=R1 TO  R50(1).

EXECUTE.

 

NIIPS / CSEO

SYNTAX FILES

valferes@fpce.uc.pt

Última actualização: 2003-04-18