SPSS: PROGRAMAS E ROTINAS COMPLEMENTARES (SYNTAX FILES)

 

Estatísticas Descritivas e Distribuições

 

Medidas de Simetria e de Curtose Baseadas em Quantis
Coeficientes de Bowley e Moors

Esta sintaxe calcula duas medidas baseadas em quantis: uma medida de simetria (coeficiente de Bowley) e uma medida de curtose (coeficiente de Moors). Mais exactamente, a sintaxe determina os octis (os sete valores que dividem uma distribuição ordenada em oito partes iguais – ver Quadro 1 e Nota) e calcula os dois coeficientes de acordo com as fórmulas do Quadro 2.

Para efeitos de ilustração, gerou-se a variável VARX, uma série de 1000 observações (M=100, DP=15), com uma distribuição teórica normal. Espera-se, pois, que a distribuição observada seja simétrica e mesocúrtica (ver Interpretação do Output).

Para uma simulação das distribuições uniforme, binomial, normal, T, F e c2 e  determinação dos coeficientes de Bowley e de Moors, ver sintaxe anexa. Para outras medidas e testes da simetria e da curtose, ver sintaxe Teste de Normalidade de D’Agostino e Testes para a Simetria e Curtose.

Ao executar esta rotina com outros dados, deve ter os mesmos na file activa do SPSS,  sendo a variável em análise uma variável numérica com a designação VARX.

 

*** Medidas de simetria e de curtose baseadas em quantis

*** Valentim Rodrigues Alferes (Universidade de Coimbra, 2003)

*** valferes@fpce.uc.pt

** DADOS DE ILUSTRAÇÃO.

NEW FILE.

INPUT PROGRAM.

LOOP ID=1 TO 1000.

END CASE.

END LOOP.

END FILE.

END INPUT PROGRAM.

SET SEED RANDOM.

COMPUTE VARX=RV.NORMAL(100,15).

EXECUTE.

 

** Quando tem os dados na file activa, a sintaxe começa aqui.

GRAPH/HISTOGRAM(NORMAL)=VARX/TITLE= 'HISTOGRAMA'.

SORT CASES BY VARX(A).

SAVE OUTFILE=DADOS.

RANK VARIABLES=VARX(A)/PROPORTION/NTILES(8)/PRINT=NO

/TIES=CONDENSE/FRACTION=VW.

RANK VARIABLES=VARX(D) BY NVARX/RANK/PRINT=NO/TIES=CONDENSE.

RANK VARIABLES=VARX(A) BY NVARX/RANK/PRINT=NO/TIES=CONDENSE.

SEL IF(RVARX=1 OR RAN001=1).

EXECUTE.

COMPUTE K=$CASENUM-1.

EXECUTE.

SEL IF(K>0 AND K<15).

EXECUTE.

COMPUTE LAG_X=LAG(VARX,1).

COMPUTE LAG_P=LAG(PVARX,1).

EXECUTE.

SEL IF(RAN001=1).

EXECUTE.

COMPUTE PER=$CASENUM*0.125.

COMPUTE A=VARX-LAG_X.

COMPUTE C=PER-LAG_P.

COMPUTE D=PVARX-LAG_P.

COMPUTE X=A*C/D.

COMPUTE OCTIL=LAG_X+X.

FORMATS OCTIL(F8.2).

SUMMARIZE/TABLES=OCTIL/FORMAT=LIST NOCASENUM TOTAL/TITLE='Octis 1 a 7'

/CELLS=NONE.

FLIP VARIABLES=OCTIL.

COMPUTE SIMETRIA=(VAR006+VAR002-(2*VAR004))/(VAR006-VAR002).

COMPUTE CURTOSE=((VAR007-VAR005)+(VAR003-VAR001))/(VAR006-VAR002).

FORMATS SIMETRIA(F8.4) CURTOSE(F15.4).

SUMMARIZE/TABLES=SIMETRIA CURTOSE/FORMAT=LIST NOCASENUM TOTAL

/TITLE='Medidas de simetria e de curtose'/CELLS=NONE.

GET FILE=DADOS.

Output

*** Medidas de simetria e de curtose baseadas em quantis

 

[...]

Graph

 

 

[...]

 

Octis 1 a 7

 

OCTIL

1

83,94

2

90,26

3

95,32

4

99,68

5

104,55

6

109,83

7

117,17

 

[...]

 

Medidas de simetria e de curtose

 

SIMETRIA

CURTOSE

1

,0376

1,2261

 

 
GET FILE=DADOS.

Interpretação do output

Atendendo aos valores padrão do Quadro 2 e em conformidade com o que seria de esperar (distribuição normal da população a partir da qual os dados foram gerados), a distribuição obtida é simétrica (coeficiente de Bowley = 0.0376) e mesocúrtica (coeficiente de Moors = 1.2261).

 

 

Quadro 1 - Quantis

Percentil

Octil

Quartil

12.5

O1

-

25.0

O2

Q1

37.5

O3

-

50.0

O4

Q2 = Mediana

62.5

O5

-

75.0

O6

Q3

87.5

O7

-

 

 

Quadro 2 - Medidas de Simetria (coeficiente de Bowley) e de
Curtose (coeficiente de Moors) baseadas em quantis

- 1

Distribuição assimétrica à esquerda (negativamente assimétrica) extrema

0

Distribuição simétrica

1

Distribuição assimétrica à direita (positivamente assimétrica) extrema

0

Distribuição platicúrtica extrema

1.233

Distribuição mesocúrtica

+ ¥

Distribuição leptocúrtica extrema

Nota

Os octis 1 a 7 coincidem, respectivamente, com os percentis 12.5, 25.0, 37.5, 50.0, 62.5, 75.0 e 87.5 (ver Quadro 1). Se apenas pretende obter os diversos quantis de uma distribuição pode utilizar diferentes menus da Interface Gráfica do SPSS (Analyze/Descriptives Statistics/Frequencies, Analyze/Descriptives Statistics/Explore ou Transform/Rank Cases...) ou correr uma das duas de sintaxes abaixo:

 

** Obtenção de percentis previamente especificados pelo utlizador.

* Introduza na linha a vermelho os percentis pretendidos (no exemplo,

* pedem-se os sete octis da variável VARX.

FREQUENCIES VARIABLES=VARX/FORMAT=NOTABLE

/PERCENTILES= 12.5 25.0 37.5 50.0 62.5 75.0 87.5.

Frequencies

Statistics
VARX

N

Valid

1000

 

Missing

0

 

Percentiles

12,5

83,94

 

25

90,26

 

37,5

95,32

 

50

99,68

 

62,5

104,55

 

75

109,83

 

87,5

117,17

 

 

 

 

** Divisão de uma variável ordenada em N partes.

* Introduza no local assinalado a vermelho o número de partes

* (no exemplo, pedem-se os sete octis da variável VARX).

FREQUENCIES VARIABLES=VARX/NTILES = 8.

Frequencies

Statistics
VARX

N

Valid

1000

 

Missing

0

 

Percentiles

12,5

83,94

 

25

90,26

 

37,5

95,32

 

50

99,68

 

62,5

104,55

 

75

109,83

 

87,5

117,17

 

 

[...]

 

Para uma sistematização dos quantis (mediana, quartis, octis, stanines, decis e percentis), ver quadros na sintaxe anexa.

Referência

Zar, J. H. (1996). Biostatistical analysis (3rd ed.). Upper Saddle River, NJ: Prentice-Hall.

 

NIIPS / CSEO

SYNTAX FILES

valferes@fpce.uc.pt

Última actualização: 2003-05-02