* Encoding: UTF-8.
** As cinco linhas que se seguem criam, para efeitos de 
** ilustração, uma file activa com os dados de Kirk (1995). 
DATA LIST FREE /A(F8.0) VD(F8.0).
BEGIN DATA
1 4 1 6 1 3 1 3 1 1 1 3 1 2 1 2 2 4 2 5 2 4 2 3 2 2 2 3 2 4 2 3 3 5 
3 6 3 5 3 4 3 3 3 4 3 3 3 4 4 3 4 5 4 6 4 5 4 6 4 7 4 8 4 10 
END DATA.

** Quando já tem os dados na file activa, a sintaxe começa aqui.
*** ANOVA unifactorial: Medidas de associação e Tamanho do efeito
*** Valentim Rodrigues Alferes (Universidade de Coimbra, 2003)
*** valferes@fpce.uc.pt

** PARTE 1.

* Introduza o alfa para o cálculo do poder (por defeito, alfa = .05).
UNIANOVA VD BY A/PRINT=DESCRIPTIVE ETASQ OPOWER/CRITERIA=ALPHA(.05)
/EMMEANS=TABLES(OVERALL)/EMMEANS=TABLES(A)/DESIGN=A.

** PARTE 2. 

COMPUTE K=1.
EXECUTE.
SORT CASES BY A(A).
AGGREGATE/OUTFILE='%temp%\FOUT1'/BREAK=K/M_G=MEAN(VD)/N_TRAT=MAX(A)/N_G=N.
MATCH FILES/FILE=*/TABLE='%temp%\FOUT1'/BY K.
EXECUTE.
AGGREGATE/OUTFILE='%temp%\FOUT2'/BREAK=A/M_A=MEAN(VD)/N_A=N.
MATCH FILES/FILE=*/TABLE='%temp%\FOUT2'/BY A.
EXECUTE.
COMPUTE SS_BET=(M_A-M_G)**2.
COMPUTE SS_WIT=(VD-M_A)**2.
EXECUTE.
AGGREGATE/OUTFILE=*/BREAK=K/N_TRAT=MEAN(N_TRAT)/N_G=MEAN(N_G) 
/N_A=MEAN(N_A)/SS_BET=SUM(SS_BET)/SS_WIT=SUM(SS_WIT).
COMPUTE MS_BET=SS_BET/(N_TRAT-1).
COMPUTE COMV_ERR=SS_WIT/(N_G-N_TRAT).
COMPUTE COMV_A=((N_TRAT-1)/N_G)*(MS_BET-COMV_ERR).
COMPUTE ETA_QUA=SS_BET/(SS_BET+SS_WIT).
COMPUTE ETA=SQR(ETA_QUA).
COMPUTE OME_QUA=COMV_A/(COMV_A+COMV_ERR).
COMPUTE OME=SQR(OME_QUA).
COMPUTE F_COHEN=SQR(OME_QUA/(1-OME_QUA)).
EXECUTE.
FORMATS COMV_ERR TO F_COHEN (F8.3).
SUMMARIZE/TABLES=COMV_A COMV_ERR/FORMAT=LIST 
NOCASENUM TOTAL/TITLE='Componentes da Variância'/CELLS=NONE.
SUMMARIZE/TABLES=ETA ETA_QUA/FORMAT=LIST NOCASENUM
NOTOTAL/TITLE='Eta e Eta Quadrado'/CELLS=NONE.
SUMMARIZE/TABLES=OME OME_QUA/FORMAT=LIST NOCASENUM
NOTOTAL/TITLE='Omega e Omega Quadrado'/CELLS=NONE.
SUMMARIZE/TABLES=F_COHEN/FORMAT=LIST NOCASENUM 
NOTOTAL/TITLE='f de Cohen'/CELLS=NONE.