** As seis linhas que se seguem criam, para efeitos de ilustração,
** uma file activa com os dados de Keppel (1991).
DATA LIST FREE /A(F8.0) B(F8.0) VD(F8.0).
BEGIN DATA
1 1 1 1 1 4 1 1 0 1 1 7 2 1 13 2 1 5 2 1 7 2 1 15 3 1 9 3 1 16 3 1 18 
3 1 13 1 2 15 1 2 6 1 2 10 1 2 13 2 2 6 2 2 18 2 2 9 2 2 15 3 2 14 3 
2 7 3 2 6 3 2 13 
END DATA.

** Quando já tem os dados na file activa, a sintaxe começa aqui.
*** ANOVA bifactorial: Medidas de associação e Tamanho do efeito
*** Valentim Rodrigues Alferes (Universidade de Coimbra, 2003)
*** valferes@fpce.uc.pt

** PARTE 1.

* Introduza o alfa para o cálculo do poder (por defeito, alfa = .05).
UNIANOVA VD BY A B/PRINT=DESCRIPTIVE ETASQ OPOWER/CRITERIA=ALPHA(.05)
/EMMEANS=TABLES(OVERALL)/EMMEANS=TABLES(A)/EMMEANS=TABLES(B)
/EMMEANS=TABLES(A*B)/DESIGN=A B A*B.

** PARTE 2. 

COMPUTE K=1.
EXECUTE.
AGGREGATE/OUTFILE='%temp%\OUT_0'/BREAK=K/M_G=MEAN(VD)/N_G=N.
MATCH FILES/FILE=*/TABLE='%temp%\OUT_0'/BY K.
EXECUTE.
SORT CASES BY A(A) B(A).
COMPUTE CELUL=A*100+B.
EXECUTE.
AUTORECODE VARIABLES=CELUL/INTO CELULA.
AGGREGATE/OUTFILE='%temp%\OUT_1'/BREAK=CELULA/M_AB=MEAN(VD)/N_AB=N.
MATCH FILES/FILE=*/TABLE='%temp%\OUT_1'/BY CELULA.
EXECUTE.
AGGREGATE/OUTFILE='%temp%\OUT_2'/BREAK=A/M_A=MEAN(VD)/N_A=N.
MATCH FILES/FILE=*/TABLE='%temp%\OUT_2'/BY A.
EXECUTE.
SORT CASES BY B(A).
AGGREGATE/OUTFILE='%temp%\OUT_3'/BREAK=B/M_B=MEAN(VD)/N_B=N.
MATCH FILES/FILE=*/TABLE='%temp%\OUT_3'/BY B.
EXECUTE.
COMPUTE D2_A=(M_A-M_G)**2.
COMPUTE D2_B=(M_B-M_G)**2.
COMPUTE D2_ERRO=(VD-M_AB)**2.
COMPUTE D2_G=(VD-M_G)**2.
EXECUTE.
AGGREGATE/OUTFILE=*/BREAK=K/N=MEAN(N_AB)/N_T_A=MAX(A)
/N_T_B=MAX(B)/SS_A=SUM(D2_A)/SS_B=SUM(D2_B)
/SS_ERRO=SUM(D2_ERRO)/SS_TOT=SUM(D2_G).
COMPUTE SS_AB=SS_TOT-SS_A-SS_B-SS_ERRO.
COMPUTE GL_A=N_T_A-1.
COMPUTE GL_B=N_T_B-1.
COMPUTE GL_AB=GL_A*GL_B.
COMPUTE GL_ERRO=N*N_T_A*N_T_B-GL_A-GL_B-GL_AB-1.
COMPUTE MS_A=SS_A/GL_A.
COMPUTE MS_B=SS_B/GL_B.
COMPUTE MS_AB=SS_AB/GL_AB.
COMPUTE MS_ERRO=SS_ERRO/GL_ERRO.
COMPUTE COMV_A=(GL_A*(MS_A-MS_ERRO))/(N_T_A*N_T_B*N).
COMPUTE COMV_B=(GL_B*(MS_B-MS_ERRO))/(N_T_A*N_T_B*N).
COMPUTE COMV_AB=(GL_AB*(MS_AB-MS_ERRO))/(N_T_A*N_T_B*N).
COMPUTE COMV_ERR=MS_ERRO.
COMPUTE COMV_TOT=SUM(COMV_A TO COMV_ERR).
COMPUTE ETA_A=SS_A/SS_TOT.
COMPUTE ETA_B=SS_B/SS_TOT.
COMPUTE ETA_AB=SS_AB/SS_TOT.
COMPUTE P_ETA_A=SS_A/(SS_A+SS_ERRO).
COMPUTE P_ETA_B=SS_B/(SS_B+SS_ERRO).
COMPUTE P_ETA_AB=SS_AB/(SS_AB+SS_ERRO).
COMPUTE OME_A=COMV_A/COMV_TOT.
COMPUTE OME_B=COMV_B/COMV_TOT.
COMPUTE OME_AB=COMV_AB/COMV_TOT.
COMPUTE P_OME_A=COMV_A/(COMV_A+COMV_ERR).
COMPUTE P_OME_B=COMV_B/(COMV_B+COMV_ERR).
COMPUTE P_OME_AB=COMV_AB/(COMV_AB+COMV_ERR).
COMPUTE F_COH_A=SQR(P_OME_A/(1-P_OME_A)).
COMPUTE F_COH_B=SQR(P_OME_B/(1-P_OME_B)).
COMPUTE F_COH_AB=SQR(P_OME_AB/(1-P_OME_AB)).
EXECUTE.
FORMATS COMV_A TO F_COH_AB (F8.3).
SUMMARIZE/TABLES=COMV_A COMV_B COMV_AB COMV_ERR/FORMAT=LIST 
NOCASENUM TOTAL/TITLE='Componentes da Variância'/CELLS=NONE.
SUMMARIZE/TABLES=ETA_A ETA_B ETA_AB/FORMAT=LIST NOCASENUM
NOTOTAL/TITLE='Eta Quadrado'/CELLS=NONE.
SUMMARIZE/TABLES=P_ETA_A P_ETA_B P_ETA_AB/FORMAT=LIST 
NOCASENUM NOTOTAL/TITLE='Eta Quadrado Parcial'/CELLS=NONE.
SUMMARIZE/TABLES=OME_A OME_B OME_AB/FORMAT=LIST 
NOCASENUM NOTOTAL/TITLE='Omega Quadrado'/CELLS=NONE.
SUMMARIZE/TABLES=P_OME_A P_OME_B P_OME_AB/FORMAT=LIST 
NOCASENUM NOTOTAL/TITLE='Omega Quadrado Parcial'/CELLS=NONE.
SUMMARIZE/TABLES=F_COH_A F_COH_B F_COH_AB/FORMAT=LIST NOCASENUM 
NOTOTAL/TITLE='f de Cohen'/CELLS=NONE.