SPSS: PROGRAMAS E ROTINAS COMPLEMENTARES (SYNTAX FILES)

 

Análise da Variância

 

Análise Bifactorial da Variância

Medidas de Associação e do Tamanho do Efeito e Poder Observado

Esta sintaxe efectua uma análise da variância bifactorial de um plano (bi)factorial completamente aleatorizado (também conhecida por ANOVA Factorial AB). O utilizador deve ter os dados na file activa do SPSS, designando os factores ou variáveis independentes por A e por B e a variável dependente por VD. Em relação à sintaxe propriamente dita, apenas lhe é pedido que indique o valor de alfa para o cálculo do poder.

O output divide-se em duas partes:

Parte 1

Média, desvio-padrão e N (globais, marginais e por condição ou grupo); quadro clássico da ANOVA, eta quadrado, eta quadrado parcial, poder observado, R2, R2ajust.; erros-padrão das médias e intervalos de confiança (esta parte do output é idêntica à que pode obter no menu Analyze / General Linear Model / Univariate... da Interface Gráfica).

Parte 2

Componentes da variância, medidas de associação (eta quadrado, eta quadrado parcial, omega quadrado e omega quadrado parcial) e do tamanho do efeito (f de Cohen) [para uma interpretação, cf. Medidas de Associação e do Tamanho do Efeito na Análise da Variância].

No exemplo (Keppel, 1991, p. 214, Quadro 10-6), pretende-se estudar a influência de certas drogas (Factor A) e da privação de alimentos (Factor B) na aprendizagem (variável dependente). O Factor A comporta três níveis (1 = Controlo; 2 = Droga X; 3 = Droga Y) e o Factor B dois níveis (1 = 1 hora de deprivação de alimentos; 2 = 24 horas de deprivação de alimentos). A medida da variável dependente é o número de erros cometidos em 20 ensaios de uma tarefa de discriminação de objectos. Foram distribuídos aleatoriamente 24 sujeitos (macacos) pelas 6 condições experimentais (4 sujeitos por condição; para os procedimentos de aleatorização ou distribuição aleatória dos sujeitos pelas condições experimentais em planos factoriais, cf. Alferes, 1997 e outra sintaxe neste site).

Desde que os níveis dos factores ou variáveis independentes correspondam a variáveis numéricas, designadas, respectivamente, por A e por B, e a variável dependente seja igualmente uma variável numérica com a designação de VD, pode utilizar esta sintaxe sem alterações para qualquer plano semelhante (com os mesmos ou com um número diferente de níveis para qualquer dos factores).

** As seis linhas que se seguem criam, para efeitos de ilustração,

** uma file activa com os dados de Keppel (1991).

DATA LIST FREE /A(F8.0) B(F8.0) VD(F8.0).

BEGIN DATA

1 1 1 1 1 4 1 1 0 1 1 7 2 1 13 2 1 5 2 1 7 2 1 15 3 1 9 3 1 16 3 1 18

3 1 13 1 2 15 1 2 6 1 2 10 1 2 13 2 2 6 2 2 18 2 2 9 2 2 15 3 2 14 3

2 7 3 2 6 3 2 13

END DATA.

 

** Quando já tem os dados na file activa, a sintaxe começa aqui.

*** ANOVA bifactorial: Medidas de associação e Tamanho do efeito

*** Valentim Rodrigues Alferes (Universidade de Coimbra, 2003)

*** valferes@fpce.uc.pt

 

** PARTE 1.

 

* Introduza o alfa para o cálculo do poder (por defeito, alfa = .05).

UNIANOVA VD BY A B/PRINT=DESCRIPTIVE ETASQ OPOWER/CRITERIA=ALPHA(.05)

/EMMEANS=TABLES(OVERALL)/EMMEANS=TABLES(A)/EMMEANS=TABLES(B)

/EMMEANS=TABLES(A*B)/DESIGN=A B A*B.

 

** PARTE 2.

 

COMPUTE K=1.

EXECUTE.

AGGREGATE/OUTFILE=OUT_0/BREAK=K/M_G=MEAN(VD)/N_G=N.

MATCH FILES/FILE=*/TABLE=OUT_0/BY K.

EXECUTE.

SORT CASES BY A(A) B(A).

COMPUTE CELUL=A*100+B.

EXECUTE.

AUTORECODE VARIABLES=CELUL/INTO CELULA.

AGGREGATE/OUTFILE=OUT_1/BREAK=CELULA/M_AB=MEAN(VD)/N_AB=N.

MATCH FILES/FILE=*/TABLE=OUT_1/BY CELULA.

EXECUTE.

AGGREGATE/OUTFILE=OUT_2/BREAK=A/M_A=MEAN(VD)/N_A=N.

MATCH FILES/FILE=*/TABLE=OUT_2/BY A.

EXECUTE.

SORT CASES BY B(A).

AGGREGATE/OUTFILE=OUT_3/BREAK=B/M_B=MEAN(VD)/N_B=N.

MATCH FILES/FILE=*/TABLE=OUT_3/BY B.

EXECUTE.

COMPUTE D2_A=(M_A-M_G)**2.

COMPUTE D2_B=(M_B-M_G)**2.

COMPUTE D2_ERRO=(VD-M_AB)**2.

COMPUTE D2_G=(VD-M_G)**2.

EXECUTE.

AGGREGATE/OUTFILE=*/BREAK=K/N=MEAN(N_AB)/N_T_A=MAX(A)

/N_T_B=MAX(B)/SS_A=SUM(D2_A)/SS_B=SUM(D2_B)

/SS_ERRO=SUM(D2_ERRO)/SS_TOT=SUM(D2_G).

COMPUTE SS_AB=SS_TOT-SS_A-SS_B-SS_ERRO.

COMPUTE GL_A=N_T_A-1.

COMPUTE GL_B=N_T_B-1.

COMPUTE GL_AB=GL_A*GL_B.

COMPUTE GL_ERRO=N*N_T_A*N_T_B-GL_A-GL_B-GL_AB-1.

COMPUTE MS_A=SS_A/GL_A.

COMPUTE MS_B=SS_B/GL_B.

COMPUTE MS_AB=SS_AB/GL_AB.

COMPUTE MS_ERRO=SS_ERRO/GL_ERRO.

COMPUTE COMV_A=(GL_A*(MS_A-MS_ERRO))/(N_T_A*N_T_B*N).

COMPUTE COMV_B=(GL_B*(MS_B-MS_ERRO))/(N_T_A*N_T_B*N).

COMPUTE COMV_AB=(GL_AB*(MS_AB-MS_ERRO))/(N_T_A*N_T_B*N).

COMPUTE COMV_ERR=MS_ERRO.

COMPUTE COMV_TOT=SUM(COMV_A TO COMV_ERR).

COMPUTE ETA_A=SS_A/SS_TOT.

COMPUTE ETA_B=SS_B/SS_TOT.

COMPUTE ETA_AB=SS_AB/SS_TOT.

COMPUTE P_ETA_A=SS_A/(SS_A+SS_ERRO).

COMPUTE P_ETA_B=SS_B/(SS_B+SS_ERRO).

COMPUTE P_ETA_AB=SS_AB/(SS_AB+SS_ERRO).

COMPUTE OME_A=COMV_A/COMV_TOT.

COMPUTE OME_B=COMV_B/COMV_TOT.

COMPUTE OME_AB=COMV_AB/COMV_TOT.

COMPUTE P_OME_A=COMV_A/(COMV_A+COMV_ERR).

COMPUTE P_OME_B=COMV_B/(COMV_B+COMV_ERR).

COMPUTE P_OME_AB=COMV_AB/(COMV_AB+COMV_ERR).

COMPUTE F_COH_A=SQR(P_OME_A/(1-P_OME_A)).

COMPUTE F_COH_B=SQR(P_OME_B/(1-P_OME_B)).

COMPUTE F_COH_AB=SQR(P_OME_AB/(1-P_OME_AB)).

EXECUTE.

FORMATS COMV_A TO F_COH_AB (F8.3).

SUMMARIZE/TABLES=COMV_A COMV_B COMV_AB COMV_ERR/FORMAT=LIST

NOCASENUM TOTAL/TITLE='Componentes da Variância'/CELLS=NONE.

SUMMARIZE/TABLES=ETA_A ETA_B ETA_AB/FORMAT=LIST NOCASENUM

NOTOTAL/TITLE='Eta Quadrado'/CELLS=NONE.

SUMMARIZE/TABLES=P_ETA_A P_ETA_B P_ETA_AB/FORMAT=LIST

NOCASENUM NOTOTAL/TITLE='Eta Quadrado Parcial'/CELLS=NONE.

SUMMARIZE/TABLES=OME_A OME_B OME_AB/FORMAT=LIST

NOCASENUM NOTOTAL/TITLE='Omega Quadrado'/CELLS=NONE.

SUMMARIZE/TABLES=P_OME_A P_OME_B P_OME_AB/FORMAT=LIST

NOCASENUM NOTOTAL/TITLE='Omega Quadrado Parcial'/CELLS=NONE.

SUMMARIZE/TABLES=F_COH_A F_COH_B F_COH_AB/FORMAT=LIST NOCASENUM

NOTOTAL/TITLE='f de Cohen'/CELLS=NONE.

Text File

SPSS Syntax File

 
** As seis linhas que se seguem criam, para efeitos de ilustração,
 
[...]
 
** PARTE 1.
 
[...]

 

Univariate Analysis of Variance

Between-Subjects Factors

 

N

A

1

8

2

8

3

8

B

1

12

2

12

 

Descriptive Statistics
Dependent Variable: VD

A

B

Mean

Std. Deviation

N

1

1

3,00

3,162

4

2

11,00

3,916

4

Total

7,00

5,398

8

2

1

10,00

4,761

4

2

12,00

5,477

4

Total

11,00

4,870

8

3

1

14,00

3,916

4

2

10,00

4,082

4

Total

12,00

4,276

8

Total

1

9,00

5,970

12

2

11,00

4,200

12

Total

10,00

5,150

24

 

 

Tests of Between-Subjects Effects
Dependent Variable: VD

Source

Type III Sum of Squares

df

Mean Square

F

Sig.

Partial Eta Squared

Noncent. Parameter

Observed Power(a)

Corrected Model

280,000(b)

5

56,000

3,055

,036

,459

15,273

,742

Intercept

2400,000

1

2400,000

130,909

,000

,879

130,909

1,000

A

112,000

2

56,000

3,055

,072

,253

6,109

,517

B

24,000

1

24,000

1,309

,268

,068

1,309

,192

A * B

144,000

2

72,000

3,927

,038

,304

7,855

,630

Error

330,000

18

18,333

 

 

 

 

 

Total

3010,000

24

 

 

 

 

 

 

Corrected Total

610,000

23

 

 

 

 

 

 

a Computed using alpha = ,05

b R Squared = ,459 (Adjusted R Squared = ,309)

 

Estimated Marginal Means

1. Grand Mean
Dependent Variable: VD

Mean

Std. Error

95% Confidence Interval

 

Lower Bound

Upper Bound

 

10,000

,874

8,164

11,836

 

 

2. A
Dependent Variable: VD

 

Mean

Std. Error

95% Confidence Interval

A

Lower Bound

Upper Bound

1

7,000

1,514

3,820

10,180

2

11,000

1,514

7,820

14,180

3

12,000

1,514

8,820

15,180

 

3. B
Dependent Variable: VD

 

Mean

Std. Error

95% Confidence Interval

B

Lower Bound

Upper Bound

1

9,000

1,236

6,403

11,597

2

11,000

1,236

8,403

13,597

 

4. A * B
Dependent Variable: VD

 

Mean

Std. Error

95% Confidence Interval

A

B

Lower Bound

Upper Bound

1

1

3,000

2,141

-1,498

7,498

2

11,000

2,141

6,502

15,498

2

1

10,000

2,141

5,502

14,498

2

12,000

2,141

7,502

16,498

3

1

14,000

2,141

9,502

18,498

2

10,000

2,141

5,502

14,498

 

 
** PARTE 2.
 
[...]
 
SUMMARIZE/TABLES=COMV_A COMV_B COMV_AB COMV_ERR/FORMAT=LIST
NOCASENUM TOTAL/TITLE='Componentes da Variância'/CELLS=NONE.

 

[...]
 

 

Componentes da Variância

 

COMV_A

COMV_B

COMV_AB

COMV_ERR

1

3,139

,236

4,472

18,333

 

 
SUMMARIZE/TABLES=ETA_A ETA_B ETA_AB/FORMAT=LIST NOCASENUM
NOTOTAL/TITLE='Eta Quadrado'/CELLS=NONE.

 

[...]
 

 

Eta Quadrado

 

ETA_A

ETA_B

ETA_AB

1

,184

,039

,236

 

 
SUMMARIZE/TABLES=P_ETA_A P_ETA_B P_ETA_AB/FORMAT=LIST
NOCASENUM NOTOTAL/TITLE='Eta Quadrado Parcial'/CELLS=NONE.

 

[...]
 

 

Eta Quadrado Parcial

 

P_ETA_A

P_ETA_B

P_ETA_AB

1

,253

,068

,304

 

 
SUMMARIZE/TABLES=OME_A OME_B OME_AB/FORMAT=LIST
NOCASENUM NOTOTAL/TITLE='Omega Quadrado'/CELLS=NONE.

 

[...]
 

 

Omega Quadrado

 

OME_A

OME_B

OME_AB

1

,120

,009

,171

 

 
SUMMARIZE/TABLES=P_OME_A P_OME_B P_OME_AB/FORMAT=LIST
NOCASENUM NOTOTAL/TITLE='Omega Quadrado Parcial'/CELLS=NONE.

 

[...]
 

 

Omega Quadrado Parcial

 

P_OME_A

P_OME_B

P_OME_AB

1

,146

,013

,196

 

 
SUMMARIZE/TABLES=F_COH_A F_COH_B F_COH_AB/FORMAT=LIST NOCASENUM
NOTOTAL/TITLE='f de Cohen'/CELLS=NONE.

 

[...]
 

 

f de Cohen

 

F_COH_A

F_COH_B

F_COH_AB

1

,414

,113

,494

 

 

Referências

Alferes, V. R. (1997). Investigação científica em psicologia: Teoria e prática. Coimbra: Almedina.

Keppel, G. (1991). Design and analysis: A researcher’s handbook (3rd ed.). Upper Saddle River, NJ: Prentice Hall.

 

NIIPS / CSEO

SYNTAX FILES

valferes@fpce.uc.pt

Última actualização: 2003-04-18